home *** CD-ROM | disk | FTP | other *** search
/ EnigmA Amiga Run 1995 November / EnigmA AMIGA RUN 02 (1995)(G.R. Edizioni)(IT)[!][issue 1995-11][Skylink CD].iso / earcd / giochi / aboulder.lha / ABoulderDash1.0 / extgfx.s < prev    next >
Text File  |  1995-08-27  |  29KB  |  1,325 lines
  1.     opt    L+
  2.     opt    O2+
  3.     opt    OW-
  4.  
  5. *==========================================
  6. *
  7. * File:        ExtGfx.s
  8. * Version:     6
  9. * Revision:    0
  10. * Created:     ??/??/????
  11. * By:          FNC Slothouber
  12. * Last Update: 12-IV-1993
  13. * By:          FNC Slothouber
  14. * 
  15. *
  16. *==========================================
  17.  
  18.     XREF    _IntuitionBase
  19.     XREF    _GfxBase
  20.     XREF    _DOSBase
  21.  
  22.     XDEF    AllocRasters
  23.     XDEF    FreeRasters
  24.     XDEF    EG_AllocBitMap
  25.     XDEF    EG_FreeBitMap
  26.     XDEF    GetPicture
  27.     XDEF    ClearBitMap
  28.     XDEF    GetDisplay
  29.     XDEF    FreeDisplay
  30.     XDEF    CreatePort
  31.     XDEF    DeletePort
  32.     XDEF    CreateStdIO
  33.     XDEF    CreateExtIO
  34.     XDEF    DeleteStdIO
  35.     XDEF    DeleteExtIO
  36.  
  37.     incdir    "include:"
  38.     include    exec/types.i
  39.     include    exec/nodes.i
  40.     include    exec/lists.i
  41.     include    exec/io.i
  42.     include    exec/exec_lib.i
  43.     include    exec/libraries.i
  44.     include    exec/initializers.i
  45.     include    exec/resident.i
  46.     include    exec/memory.i
  47.     include    exec/alerts.i
  48.     include    graphics/graphics_lib.i
  49.     include    graphics/view.i        ; For GetDisplay.
  50.     include    hardware/custom.i    ; For BlitCopyMem.
  51.     include    libraries/dos_lib.i
  52.     include libraries/dos.i
  53.     include    extgfx.i
  54.  
  55. ***********  MACRO's  ************************
  56.  
  57. beginlnk macro
  58. count    set    0
  59.     endm
  60. long    macro
  61. count    set    count-4
  62. \1    equ    count
  63.     endm
  64. word    macro
  65. count    set    count-2
  66. \1    equ    count
  67.     endm
  68. sizze    macro
  69. \1    equ    count
  70.     endm
  71.  
  72. CALLSYS    macro        same as CALLEX
  73.     CALLLIB    _LVO\1
  74.     endm
  75.  
  76. CLEAR    macro        quick method to clear a register
  77.     MOVEQ #0,\1
  78.     endm
  79.  
  80. CALLEX    macro
  81.     move.l    a6,-(sp)
  82.     move.l    4,a6
  83.     jsr    _LVO\1(a6)
  84.     move.l    (sp)+,a6
  85.     endm
  86.  
  87. CALLGFX    macro
  88.     move.l    a6,-(sp)
  89.     move.l    _GfxBase,a6
  90.     jsr    _LVO\1(a6)
  91.     move.l    (sp)+,a6
  92.     endm
  93.  
  94. CALLDOSF macro
  95.     move.l    a6,-(sp)
  96.     move.l    _DOSBase,a6
  97.     jsr    _LVO\1(a6)
  98.     move.l    (sp)+,a6
  99.     endm
  100.  
  101. CALLINTF macro
  102.     move.l    a6,-(sp)
  103.     move.l    _IntuitionBase,a6
  104.     jsr    _LVO\1(a6)
  105.     move.l    (sp)+,a6
  106.     endm
  107.  
  108. ******* ExtGfx.s/AllocRasters ******************************************
  109. *
  110. *   NAME    
  111. *    AllocRasters -- Allocate a number of bitplanes (rasters).
  112. *   SYNOPSIS
  113. *    succes = AllocRasters(BitMap)
  114. *    d0              A0
  115. *    LONG AllocRaster(struct BitMap *)
  116. *   FUNCTION
  117. *    Allocate "depth" BitPlanes, using the size given in the
  118. *    bitmap structure.
  119. *   INPUTS
  120. *    BitMap - A pointer to a bitmap structure containing the magic
  121. *        numbers.
  122. *   RESULT
  123. *    The plane-pointers will point to the allocated bitplanes. A
  124. *    none zero value will be returned to indicate everything is OK.
  125. *    If the allocation of one of the bitplanes failed, the
  126. *    already allocated bitplanes will be deallocated, and the
  127. *    return value will be zero.
  128. *   EXAMPLE
  129. *
  130. *   NOTES
  131. *    Use this routine only if you supply your own bitmap structure,
  132. *    normaly EG_AllocBitMap performs this task for you.
  133. *   BUGS
  134. *    Only possible if the you request a depth of 8 bitplanes or more.
  135. *   SEE ALSO
  136. *    FreeRasters()
  137. ******************************************************************************
  138. *
  139. *
  140.  
  141. AlR_reg    reg    a2/a3/d2
  142.  
  143. AllocRasters
  144.     movem.l    AlR_reg,-(sp)
  145.  
  146.     move.l    a0,a2        ; Pointer to the head of the bitmap stucture.
  147.     move.l    a0,a3        ; Pointer to the bitplane pointers.
  148.  
  149.     adda.l    #bm_Planes,a3    ; Get the number of bitplanes the user wants.
  150.     moveq    #0,d2
  151.     move.b    bm_Depth(a2),d2
  152.     beq    .ll2        ; User don't want bitplanes !
  153.  
  154.     subq.w  #1,d2
  155. .ll1    moveq    #0,d0         ; Because of move.w
  156.     moveq    #0,d1
  157.     move.w  bm_BytesPerRow(a2),d0
  158.     lsl.w    #3,d0         ; Calc. number of pixels.
  159.     move.w  bm_Rows(a2),d1    ; Height.
  160.     CALLGFX AllocRaster    ; Try to allocate a bitplane.
  161.     move.l    d0,(a3)+
  162.     beq    .geterr        ; It failed.
  163.     dbra    d2,.ll1        ; Next bitplane.
  164.  
  165. .ll2    movem.l    (sp)+,AlR_reg
  166.     moveq   #-1,d0         ; Every thing OK.
  167.     rts
  168.  
  169. .geterr    move.l    a2,a0        ; An error occured
  170.     bsr    FreeRasters    ; Give back the allocated bitplanes.
  171.     movem.l    (sp)+,AlR_reg
  172.     clr.l    d0        ; ERROR!!
  173.     rts
  174.  
  175. ******* ExtGfx.s/FreeRasters ******************************************
  176. *
  177. *   NAME    
  178. *    FreeRasters -- Deallocate all bitplanes of a BitMap.
  179. *   SYNOPSIS
  180. *    FreeRasters(BitMap)
  181. *            A0
  182. *    void FreeRasters(struct BitMap *)
  183. *   FUNCTION
  184. *    Dealocate all bitplanes. Using the bitplane pointers given
  185. *    in the bitmap structure.
  186. *   INPUTS
  187. *    BitMap - A pointer to a bitmap structure
  188. *   RESULT
  189. *    None
  190. *   EXAMPLE
  191. *
  192. *   NOTES
  193. *    You can AllocRaster(NULL).
  194. *   BUGS
  195. *
  196. *   SEE ALSO
  197. *    AllocRasters()
  198. ******************************************************************************
  199. *
  200. *
  201.  
  202. FrR_r reg    a2/d2/a3
  203.  
  204. FreeRasters
  205.     move.l    a0,d0
  206.     beq.s    .exit
  207.     movem.l    FrR_r,-(sp)
  208.  
  209.     move.l    a0,a2
  210.     move.l    a0,a3
  211.     move.w  #7,d2        ; Try to deallocate all the 8 bitbplanes.
  212.     adda.l    #bm_Planes,a3
  213. .ll1    movea.l    (a3)+,a0    ; Raster Pointer
  214.     cmp.l    #0,a0        ; Is the bitplane home ?
  215.     beq.s    .ll2        ; No then don't deallocate it.
  216.     moveq    #0,d0
  217.     moveq    #0,d1
  218.     move.w  bm_BytesPerRow(a2),d0
  219.     lsl.w    #3,d0        ; Calc. display width in pix.
  220.     move.w  bm_Rows(a2),d1    ; Display height.
  221.     CALLGFX FreeRaster    ; Deallocate bitplane.
  222. .ll2    dbra    d2,.ll1
  223.  
  224.     movem.l    (sp)+,FrR_r
  225. .exit    rts
  226.  
  227. ******* ExtGfx.s/EG_AllocBitMap ******************************************
  228. *
  229. *   NAME    
  230. *    EG_AllocBitMap -- Allocate memory for a bitmap structure,
  231. *    initialize it, and allocate Rasters.
  232. *   SYNOPSIS
  233. *    BitMap,errorcode = EG_AllocBitMap(depth,width,height)
  234. *    d0     d1               d0   ,d1   ,d2
  235. *    struct BitMap *EG_AllocBitMap(ULONG,ULONG,ULONG)
  236. *   FUNCTION
  237. *    This function will allocate a bitmap structure, initialize
  238. *    it with the magic numbers and allocate the number of rasters
  239. *    you requested for.
  240. *   INPUTS
  241. *    Depth - Depth of the BitMap [0..8]
  242. *    Width - Width of the BitMap
  243. *    Height - Height of the BitMap
  244. *   RESULT
  245. *    A pointer to an initialized BitMap structure
  246. *    If there was an error, all the memory will be deallocated,
  247. *    and the function will return a NULL pointer and an error code.
  248. *
  249. *    ErrorCode:
  250. *    1 = No memory for a bitmap.
  251. *    2 = No memory for the rasters.
  252. *   EXAMPLE
  253. *
  254. *   NOTES
  255. *
  256. *   BUGS
  257. *
  258. *   SEE ALSO
  259. *    EG_FreeBitMap()
  260. ******************************************************************************
  261. *
  262. *
  263.  
  264.  
  265. EG_AllocBitMap
  266.     move.l    d7,-(sp)
  267.  
  268.     movem.l    d0/d1,-(sp)
  269.     move.l    #bm_SIZEOF,d0    ; Alloc. mem. for bitmap.
  270.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,d1
  271.     CALLEX    AllocMem
  272.     tst.l    d0
  273.     bne.s    .ll1
  274.     movem.l    (sp)+,d0/d1
  275.     moveq    #1,d7        ; Error code 1 no mem.
  276.     bra    .err1
  277.  
  278. .ll1    move.l    d0,a0        ; Init. bitmap.
  279.     movem.l    (sp)+,d0/d1
  280.     move.l    a0,-(sp)
  281.     CALLGFX InitBitMap
  282.  
  283.     move.l    (sp),a0        ; Alloc. bitplanes.
  284.     bsr    AllocRasters
  285.     tst.l    d0        ; No error?
  286.     bne    .ll2
  287.     moveq    #2,d7        ; Errorcode 2 no bitplane mem. 
  288.     bra    .err2
  289.  
  290. .ll2    move.l    (sp)+,d0    ; Pointer to the bitmap.
  291.     move.l    (sp)+,d7
  292.     rts
  293.  
  294. .err2    move.l    (sp)+,a1    ; Dealloc. bitmap.
  295.     move.l    #bm_SIZEOF,d0
  296.     CALLEX    FreeMem
  297. .err1    moveq    #0,d0        ; Something went wrong.
  298.     move.l    d7,d1        ; Error code in d2
  299.     move.l    (sp)+,d7
  300.     rts
  301.  
  302.  
  303. ******* ExtGfx.s/EG_FreeBitMap ******************************************
  304. *
  305. *   NAME    
  306. *    EG_FreeBitMap --Deallocate all the memory use by the bitmap.
  307. *   SYNOPSIS
  308. *    EG_FreeBitMap(BitMap)
  309. *           A0
  310. *    void EG_FreeBitMap(struct BitMap *)
  311. *   FUNCTION
  312. *    The function FreeRasters is used to deallocate the memory
  313. *    used by the bitplanes. Then the memory allocated to store the
  314. *    bitmap stucture is deallocted.
  315. *   INPUTS
  316. *    BitMap - A pointer to a BitMap structure
  317. *   RESULT
  318. *    None
  319. *   EXAMPLE
  320. *
  321. *   NOTES
  322. *    You can EG_FreeBitMap(NULL)
  323. *   BUGS
  324. *
  325. *   SEE ALSO
  326. *    FreeRasters(), EG_AllocBitMap()
  327. ******************************************************************************
  328. *
  329. *
  330.  
  331. EG_FreeBitMap
  332.     move.l    a0,d0
  333.     beq.s    .exit
  334.     move.l    a0,-(sp)
  335.     bsr    FreeRasters 
  336.     move.l    (sp)+,a1 
  337.     move.l    #bm_SIZEOF,d0
  338.     CALLEX    FreeMem
  339. .exit    rts
  340.  
  341.  
  342. ******* ExtGfx.s/GetPicture ******************************************
  343. *
  344. *   NAME    
  345. *    GetPicture -- Load an IFF picture file from disk
  346. *   SYNOPSIS
  347. *    error = GetPicture(filename,BitMap,Colors)
  348. *    D0           A0        A1     A2
  349. *    ULONG GetPicture(STRPTR,struct BitMap *,UWORD *)
  350. *   FUNCTION
  351. *    The file is loaded into memory. If Colors <> NULL the
  352. *    colors of the picture are placed in the array Colors is pointing
  353. *    to. If the size of the picture is unequal to the size of the
  354. *    bitmap the picture will be clipped.
  355. *   INPUTS
  356. *    filename - A null terminated string.
  357. *    BitMap - A pointer to a BitMap structure.
  358. *    Colors - A pointer to a Array of at least 32 Words, to store the
  359. *       Colors
  360. *   RESULT
  361. *    Error:
  362. *    0 = OK
  363. *    1 = File Not Found
  364. *    2 = Out Of Memory
  365. *    3 = Read Error (I/O error)  Use IOerr for more information.
  366. *    4 = Not a IFF File
  367. *    5 = Bad Unpack
  368. *    6 = No BMHD
  369. *    7 = No BODY
  370. *    8 = No CMAP
  371. *    9 = Bad CMAP ( To many colors )
  372. *    10 = Compression method not supported.
  373. *   EXAMPLE
  374. *
  375. *   NOTES
  376. *    A bitmap with a depth of 0 can be used to extract the colors
  377. *    of picture.
  378. *   BUGS
  379. *    The routine can only handle packed pictures. (using the
  380. *    byte-run algorithm.), and plain (unpacked) pictures, all
  381. *    other compression methods are not supported. Howerever at
  382. *    this writing byte-run is the only compression method used.
  383. *   SEE ALSO
  384. *
  385. ******************************************************************************
  386. *
  387. *
  388.  
  389.     beginlnk
  390.     long    GP_filename
  391.     long    GP_filehd
  392.     long    GP_mem1
  393.     long    GP_mem2
  394.     long    GP_mem3
  395.     long    GP_sizemem2
  396.     word    GP_depth    ; Number of bitplanes needed.
  397.     word    GP_width    ; Width of the picture
  398.     word    GP_height    ; Height of the picture
  399.     word    GP_compr    ; type of compression
  400.     long    GP_nr_packed    ; Nuber of bytes that form the picture.
  401.     long    GP_bitmap    ; User supplied bitmap
  402.     sizze    GP_sizeof
  403.  
  404. GP_regs    reg    d2-d7/a2-a6
  405.  
  406. GetPicture
  407.     movem.l    GP_regs,-(sp)
  408.     link    a5,#GP_sizeof
  409.     move.l    a0,GP_filename(a5)
  410.     move.l    a1,GP_bitmap(a5)
  411.     moveq    #0,d0
  412.     move.l    d0,GP_mem1(a5)    ; So error knows what is allocated
  413.     move.l    d0,GP_mem2(a5)    ; and what's not.
  414.     move.l    d0,GP_mem3(a5)
  415.     move.l    d0,GP_filehd(a5)
  416.  
  417.     move.l    a0,d1        ; Open the file.
  418.     move.l    #MODE_OLDFILE,d2
  419.     CALLDOSF Open
  420.     move.l    d0,GP_filehd(a5)
  421.     bne.s .ll1
  422.     moveq    #1,d7
  423.     bra    GP_error    ; Open failed !
  424. .ll1
  425.     moveq    #8,d0         ; Allocate public mem.
  426.     move.l    #1,d1        ; 8 bytes
  427.     CALLEX  AllocMem
  428.     move.l    d0,GP_mem1(a5)
  429.     bne.s    .ll2
  430.     moveq    #2,d7
  431.     bra    GP_error
  432. .ll2
  433.     move.l    GP_filehd(a5),d1    ; Read the first 8
  434.     move.l    GP_mem1(a5),d2        ; bytes.
  435.     moveq    #8,d3
  436.     CALLDOSF Read
  437.     bpl.s     .ll3
  438.     moveq    #3,d7
  439.     bra    GP_error        ; IOerr
  440. .ll3
  441.     move.l    GP_mem1(a5),a0        ; Is it a FORM file.
  442.     cmp.l    #"FORM",(a0)
  443.     beq    .ll4
  444.     moveq    #4,d7
  445.     bra    GP_error        ; No
  446. .ll4
  447.     move.l    4(a0),GP_sizemem2(a5)    ; Size of the IFF file.
  448.  
  449.     move.l    4(a0),d0        ; Alloceer public mem.
  450.     move.l    #1,d1
  451.     CALLEX  AllocMem
  452.     move.l    d0,GP_mem2(a5)
  453.     bne.s     .ll5
  454.     moveq     #5,d7
  455.     bra    GP_error
  456. .ll5
  457.     move.l    GP_sizemem2(a5),d3    ; Load file.
  458.     move.l    GP_filehd(a5),d1
  459.     move.l    GP_mem2(a5),d2
  460.     CALLDOSF Read
  461.     cmp.l    #-1,d0
  462.     bne.s     .ll6
  463.     moveq    #3,d7
  464.     bra    GP_error
  465. .ll6
  466.     move.l    #8*4,d0            ; Public mem for bitplane
  467.     move.l    #1,d1            ; pointers.
  468.     CALLEX  AllocMem
  469.     move.l    d0,GP_mem3(a5)
  470.     bne    .ll7
  471.     moveq     #6,d7
  472.     bra    GP_error
  473.  
  474. ** Copy bitplane pointers
  475.  
  476. .ll7
  477.     moveq    #7,d0
  478.     move.l    GP_bitmap(a5),a0
  479.     adda.l    #bm_Planes,a0
  480.     move.l    GP_mem3(a5),a1
  481. .ll8
  482.     move.l    (a0)+,(a1)+
  483.     dbra    d0,.ll8
  484.  
  485.     cmp.l    #0,a2            ; Does the user wants colors ?
  486.     beq    .geencol
  487.  
  488. ** Find color header "CMAP"
  489.  
  490.     move.l    GP_mem2(a5),a0
  491.     clr.l    d0
  492. .col0    addq.l    #1,d0
  493.     cmp.l    GP_sizemem2(a5),d0    ; End of file ?
  494.     bne.s    .col1
  495.     moveq    #8,d7            ; Yes error #8, no CMAP
  496.     bra    GP_error
  497. .col1
  498.     cmp.b    #'C',(a0)+
  499.     bne.s    .col0
  500.     cmp.b    #'M',(a0)
  501.     bne.s    .col0
  502.     cmp.b    #'A',1(a0)
  503.     bne.s    .col0
  504.     cmp.b    #'P',2(a0)
  505.     bne.s    .col0
  506.  
  507.     clr.l    d1
  508.     clr.l    d2
  509.     adda.l    #3,a0
  510.     move.l    (a0)+,d0    ; Number of entries
  511.     cmp.l    #3*32,d0
  512.     bls.s    .col2
  513.     moveq    #9,d7        ; Get colors error.
  514.     bra    GP_error
  515. .col2
  516.     move.b    (a0)+,d1    ; Assemble colors
  517.     lsl.l    #4,d1        ; and put them in an array.
  518.     or.b    (a0)+,d1
  519.     move.b    (a0)+,d2
  520.     lsr.b    #4,d2
  521.     or.b    d2,d1
  522.     move.w    d1,(a2)+
  523.     subq.w    #3,d0
  524.     bpl.s    .col3
  525.     moveq    #9,d7        ; Get colors error.
  526.     bra    GP_error
  527. .col3    bne.s    .col2
  528.  
  529. .geencol
  530.  
  531. ** format of the picture.
  532. ** find "BMHD"
  533.  
  534.     move.l    GP_mem2(a5),a0
  535.     clr.l    d0
  536. .bmh0    addq.l    #1,d0
  537.     cmp.l    GP_sizemem2(a5),d0    ; End of file ?
  538.     bne.s    .bmh1
  539.     moveq    #6,d7            ; Yes error #6, no BMHD
  540.     bra    GP_error
  541. .bmh1
  542.     cmp.b    #'B',(a0)+
  543.     bne.s    .bmh0
  544.     cmp.b    #'M',(a0)
  545.     bne.s    .bmh0
  546.     cmp.b    #'H',1(a0)
  547.     bne.s    .bmh0
  548.     cmp.b    #'D',2(a0)
  549.     bne.s    .bmh0
  550.     adda.l    #3+4,a0
  551.  
  552.     move.w    (a0)+,GP_width(a5)    ; Found width.
  553.     move.w    (a0)+,GP_height(a5)    ; Found height
  554.     addq.l    #4,a0             ; SKIP x and y position.
  555.     move.b    (a0)+,GP_depth(a5)    ; Found depth
  556.     addq.l    #1,a0            ; SKIP masking
  557.     move.b    (a0)+,d0
  558.     move.b    d0,GP_compr(A5)        ; Type of compression
  559.     cmp.b    #2,d0            ; Compression type supported ?
  560.     blt.s    .bmh2
  561.     moveq    #10,d7
  562.     bra    GP_error        ; Compression type not supported
  563. .bmh2
  564.     
  565.  
  566. ** Find body
  567.  
  568.     move.l    GP_mem2(a5),a0
  569.     moveq    #0,d0
  570. .bod0    addq.l    #1,d0
  571.     cmp.l    GP_sizemem2(a5),d0    ; End of file ?
  572.     bne.s    .bod1
  573.     moveq    #7,d7            ; Yes error #7, no BODY
  574.     bra    GP_error
  575. .bod1    cmp.b    #'B',(a0)+
  576.     bne.s    .bod0
  577.     cmp.b    #'O',(a0)
  578.     bne.s    .bod0
  579.     cmp.b    #'D',1(a0)
  580.     bne.s    .bod0
  581.     cmp.b    #'Y',2(a0)
  582.     bne.s    .bod0
  583.     adda.l    #3,a0
  584.  
  585.     move.l    (a0)+,GP_nr_packed(a5) ; Number of bytes in body.
  586.  
  587.  
  588. ** Restore picture
  589.  
  590. .unp    moveq    #0,d3
  591.     move.w    GP_width(a5),d3        ; Width pic. in bytes.
  592.     lsr.l    #3,d3
  593.     move.l    GP_bitmap(a5),a1
  594.     moveq    #0,d4
  595.     move.w    bm_BytesPerRow(a1),d4    ; Width BitMap in bytes.
  596.     move.l    d4,d5
  597.     sub.l    d3,d5            ; modulo = W_BM - W_pic.
  598.  
  599.     move.l    GP_bitmap(a5),a1    ; Number of lines.
  600.     clr.l    d7
  601.     move.w    bm_Rows(a1),d7
  602.     cmp.w    GP_height(a5),d7    ; H_pic. < H_bm ?
  603.     bls    .unp0
  604.     move.w    GP_height(a5),d7    ; Yes use height pic.
  605. .unp0    subq.w    #1,d7
  606.     
  607. .unp3    move.l    GP_mem3(a5),a2
  608.  
  609.     clr.w    d6
  610.     move.b    GP_depth(a5),d6        ; Number of bitplanes
  611.     subq.w    #1,d6
  612.  
  613. .unp2    move.l    (a2)+,a1
  614.     tst.b    GP_compr(a5)        ; Compression used ?
  615.     bne.s    .unp5            
  616.     bsr    restoreline        ; No just copy line
  617.     bra.s    .unp4            ; No error possible !
  618. .unp5    bsr    unpackaline
  619.     tst.l    d0            ; Error while unpacking ?
  620.     bne    .unp4
  621.     moveq    #5,d7            ; Yes error #5 bad unpack 
  622.     bra    GP_error
  623. .unp4    move.l    a1,-4(a2)
  624.  
  625.     dbra    d6,.unp2        ; Next bitplane.
  626.     
  627.     dbra    d7,.unp3        ; Next line.
  628.  
  629. GP_exit
  630.     clr.l d7             ; No errors.
  631. GP_error
  632.     move.l    GP_filehd(a5),d1
  633.     beq    .ll1
  634.     CALLDOSF Close
  635. .ll1
  636.     move.l    GP_mem1(a5),d1
  637.     beq    .ll2
  638.     move.l    d1,a1
  639.     moveq #8,d0
  640.     CALLEX FreeMem
  641. .ll2
  642.     move.l    GP_mem2(a5),d1
  643.     beq    .ll3
  644.     move.l    d1,a1
  645.     move.l    GP_sizemem2(a5),d0
  646.     CALLEX FreeMem
  647. .ll3
  648.     move.l    GP_mem3(a5),d1
  649.     beq    .ll4
  650.     move.l    d1,a1
  651.     move.l    #8*4,d0
  652.     CALLEX FreeMem
  653. .ll4
  654.     move.l    d7,d0
  655.     unlk    a5
  656.     movem.l    (sp)+,GP_regs
  657.     rts
  658.  
  659. restoreline    ; (source,dest,widthpic/8,widthbm/8),a0,a1,d3,d4
  660.  
  661.     suba.l    a3,a3        ; Make a NULL
  662.     cmp.l    a3,a1        ; Bitplane Home ?
  663.     beq.s    .res1
  664.     
  665.     move.l    a0,a3
  666.     move.l    a1,a4
  667.     cmp.w    d4,d3
  668.     bls.s    .res3        ; pic <= bitmap
  669.     move.w    d4,d0        ; no width = width bitmap
  670.     bra.s    .res4
  671. .res3    move.w    d3,d0        ; yes width = width pic
  672.  
  673. .res4    subq.w    #1,d0
  674. .res2    move.b    (a3)+,(a4)+    ; copy line pic to line bitmap
  675.     dbra    d0,.res2
  676.     add.l    d4,a1        ; next line in bitmap
  677.  
  678. .res1    add.l    d3,a0        ; next line in pic    
  679.     moveq    #-1,d0        ; all OK
  680.     rts    
  681.  
  682. unpackaline    ; (source,dest,widthpic/8,widthbm/8),a0,a1,d3,d4
  683.  
  684. *!!!!! Internal Routine !!!!
  685.  
  686.     suba.l    a3,a3        ; Make a NULL
  687.     clr.w    d0        ; nr = 0
  688. un1
  689.     clr.w    d1
  690.     move.b    (a0)+,d1
  691.     cmp.b    #128,d1        ; NOP
  692.     beq    npover
  693.     tst.b    d1
  694.     bpl.s    plus
  695.  
  696.     move.b (a0)+,d2
  697.     neg.b   d1
  698.  
  699. ** Herhaal volgende byte (-n)+1 maal
  700. un2    cmp.l    a3,a1        ; Bitplane home ?
  701.     beq.s    .ll1        ; No, don't dump bytes.
  702.     cmp.w    d4,d0
  703.     bhs.s    .ll1        ; bm line full, don't dump bytes
  704.  
  705.     move.b    d2,(a1)+    
  706. .ll1    addq.w  #1,d0        ; nr=nr+1
  707.     cmp.w    d3,d0
  708.     bhi.s    UpL_error    ; UnPack error to many bytes in one line!
  709.     dbf    d1,un2
  710.     bra.s    npover
  711.  
  712. **  copieer (n)+1 bytes
  713. plus    move.b    (a0)+,d2
  714.  
  715.     cmp.l    a3,a1        ; Bitplane home ?
  716.     beq.s    .ll1        ; No, don't dump bytes.
  717.     cmp.w    d4,d0
  718.     bhs.s    .ll1        ; bm line full, don't dump bytes
  719.  
  720.     move.b    d2,(a1)+ 
  721. .ll1    addq.w  #1,d0        ; nr=nr+1
  722.     cmp.w    d3,d0
  723.     bhi.s    UpL_error    ; Unpack Error to many bytes in one line!
  724.     dbf    d1,plus
  725. npover
  726.     cmp.w   d3,d0
  727.     bne.s    un1
  728.  
  729.     cmp.l    a3,a1        ; Bitplane Home ?
  730.     beq.s    .ll1        ; No, then we don't need a modulo.
  731.     tst.l    d5        ; Do we really need a modulo?
  732.     bmi.s    .ll1
  733.     adda.l    d5,a1        ; Yes, wilst bitmap larger then piciture.
  734.  
  735. .ll1    moveq    #-1,d0        ; No error.
  736.     rts
  737. UpL_error
  738.     moveq    #0,d0        ; Panic an error !!
  739.     rts
  740.  
  741. ******* ExtGfx.s/ClearBitMap ******************************************
  742. *
  743. *   NAME    
  744. *    ClearBitMap -- Clear all bitplanes
  745. *   SYNOPSIS
  746. *    ClearBitMap(BitMap)
  747. *            A0
  748. *    void ClearBitMap(struct BitMap *)
  749. *   FUNCTION
  750. *    Clear all bitplanes defined in the bitmap using the blitter.
  751. *   INPUTS
  752. *    BitMap - A pointer to a bitmap structure.
  753. *   RESULT
  754. *
  755. *   EXAMPLE
  756. *
  757. *   NOTES
  758. *
  759. *   BUGS
  760. *    Possible because of a bug in the blitter.
  761. *   SEE ALSO
  762. *
  763. ******************************************************************************
  764. *
  765. *
  766.  
  767. ClearBitMap
  768.     movem.l    a2/a3,-(sp)
  769.  
  770.     move.l    a0,a3
  771.     move.w    bm_BytesPerRow(a3),d0
  772.     lsr.w    #1,d0            ; Number of words
  773.     move.w    bm_Rows(a3),d1
  774.     lsl.w    #6,d1
  775.     or.w    d0,d1            ; Calc size of blit.
  776.  
  777.     clr.w    d0
  778.     move.b    bm_Depth(a3),d0
  779.     subq.w    #1,d0            ; Number of blits.
  780.     adda.l    #8,a3            ; Pointer to bitplane pointers
  781.  
  782.     move.l    #$dff000,a2        ; Custom Chip base addr.
  783.  
  784.     CALLGFX WaitBlit
  785.     CALLGFX OwnBlitter
  786. ** Falid for every blit.
  787.     move.w    #0,bltdmod(a2)        ; Mod D = 0
  788.     move.w    #$01f0,bltcon0(a2)    ; Use D , D=A
  789.     move.w    #$0000,bltcon1(a2)    ; no shift etc
  790.     move.w    #$ffff,bltafwm(a2)    ; ?
  791.     move.w    #$ffff,bltalwm(a2)    ; ?
  792.     move.w    #$0000,bltadat(a2)    ; 0 -> DEST
  793. .ll1
  794.     move.l    (a3)+,bltdpt(a2)    ; Clear bitplane.
  795.     move.w    d1,bltsize(a2)        ; Start  blitter
  796.     CALLGFX WaitBlit        ; Blitter finished ?
  797.     dbra    d0,.ll1            ; Next bitplane
  798.  
  799.     CALLGFX DisownBlitter
  800.     CALLGFX WaitBlit        ; ???
  801.     movem.l    (sp)+,a2/a3
  802.     rts
  803.  
  804.  
  805. ******* ExtGfx.s/GetDisplay ******************************************
  806. *
  807. *   NAME    
  808. *    GetDisplay - Allocate and initialize a display structure.
  809. *   SYNOPSIS
  810. *    display, error code =
  811. *    D0     D1    
  812. *        GetDisplay(new_Display,BitMap1,BitMap2)
  813. *               A2          A0      [A1]
  814. *    struct Display *GetDisplay(struct new_Display *,
  815. *        struct BitMap *,struct BitMap *)
  816. *   FUNCTION
  817. *    Allocate and initialize a Display Structure
  818. *    - Allocate memory for a display structure.
  819. *    - Allocate a colormap.
  820. *    - Initialize a rasinfo.
  821. *    - Initialize a Viewport.
  822. *    - Initialize a View.
  823. *    - Link the bitmap, rasinfo, viewport and view together.
  824. *    if DUALPFIELD then
  825. *        Allocate a second RastInfo.
  826. *        Link second RasInfo to first RasInfo.
  827. *        Initialize the second RasInfo.
  828. *        Link second Bitmap to second RasInfo.
  829. *
  830. *    If an error occurs all memory allocated will be deallocated.
  831. *
  832. *   INPUTS
  833. *    new_Display - A pointer to a new Display structure
  834. *        Defining: The width (in pixels) of the display. If the size
  835. *            is equal to -1, the width of the bitmap will be used.
  836. *        The height (in pixels) of the display. If the height
  837. *            is equal to -1, the height of the bitmap will be used.
  838. *        The display mode (V_HAM, V_HIRES, V_DUALPLFLD, V_LACE).
  839. *    BitMap1 - A pointer to a initialized bitmap structure.
  840. *    BitMap2 - A pointer to a initialized BitMap structure. (Only
  841. *       needed if you request DUALPLAYFIELD).
  842. *
  843. *   RESULT
  844. *    A pointer to a display structure which contains a pointer to
  845. *    a view, a viewport and a rasinfo structure. All you need to
  846. *    create a display now, is a call to makevport, mrgcopper and
  847. *    loadview.
  848. *
  849. *    If there was an error:
  850. *    A Nill pointer and a error code.
  851. *    1 = No memory for the display structure.
  852. *    2 = GetColorMap failed. 
  853. *    3 = No memory for extra RasInfo structure.
  854. *
  855. *   EXAMPLE
  856. *
  857. *    ...
  858. *    move.l    my_bitmap,a0
  859. *    sub.l    a1,a1            ; only one bitmap
  860. *    lea    new_display,a2
  861. *    CALLEXT    GetDisplay
  862. *    move.l    d0,display
  863. *    beq     error
  864. *
  865. *    move.l    display,a2
  866. *    move.l    dsp_View(a2),a0        ; Get the allocated view
  867. *    move.l    dsp_ViewPort(a2),a1    ; Get the allocated viewport
  868. *    CALLGRAF MakeVPort
  869. *    move.l    dsp_View(a2),a1
  870. *    CALLGRAF MrgCop            ; Mrg all copper list
  871. *    move.l    dsp_View(a2),a1
  872. *    CALLGRAF LoadView        ; Show the display
  873. *    ...
  874. *
  875. * new_display
  876. *    dc.w    -1            ; USE THE SIZE GIVEN IN THE BITMAP
  877. *    dc.w    -1,d1            ; USE THE SIZE GIVEN IN THE BITMAP.
  878. *    dc.w    V_HAM            ; A HOLD AND MODIFY DISPLAY
  879. *
  880. *    The display structure can be found in the file extgfx.i
  881. *   NOTES
  882. *
  883. *   BUGS
  884. *
  885. *   SEE ALSO
  886. *    FreeDisplay()
  887. ******************************************************************************
  888. *
  889. *
  890.  
  891.     beginlnk
  892.     long    gdp_BM1
  893.     long    gdp_BM2
  894.     long    gdp_ColorMap
  895.     long    gdp_dsp
  896.     word    gdp_Width
  897.     word    gdp_Height
  898.     word    gdp_Modes
  899.     sizze    gdp_sizeof
  900.  
  901. GDP_regs    reg    a2/d7
  902. GetDisplay
  903.     movem.l    GDP_regs,-(sp)
  904.  
  905.     link    a5,#gdp_sizeof
  906.  
  907.     clr.l    gdp_ColorMap(a5)
  908.     move.w    new_dsp_width(a2),gdp_Width(a5)
  909.     move.w    new_dsp_height(a2),gdp_Height(a5)
  910.     move.w    new_dsp_modes(a2),gdp_Modes(a5)
  911.     move.l    a0,gdp_BM1(a5)
  912.     move.l    a1,gdp_BM2(a5)
  913.  
  914.     lea    dsp_Template(pc),a0    ; Allocate memory for a view, 
  915.     CALLEX    AllocEntry        ; a viewport and a rasinfo structure
  916.     move.l    d0,gdp_dsp(a5)
  917.     bpl.s    .ll1
  918.     moveq.l    #1,d7
  919.     beq    gdp_error
  920.  
  921. .ll1    moveq.l    #32,d0            ; Make a colormap.
  922.     CALLGFX    GetColorMap
  923.     move.l    d0,gdp_ColorMap(a5)
  924.     bne.s    .ll2
  925.     moveq.l    #2,d7
  926.     beq    gdp_error
  927.  
  928. .ll2    move.l    gdp_BM1(a5),a0        ; Use bitmap format or use user
  929.     tst.w    gdp_Width(a5)        ; supplied format ?
  930.     bpl.s    .ll3
  931.     move.w    bm_BytesPerRow(a0),d0    ; Use bytesperrow to calculate
  932.     lsl.w    #3,d0            ; the width of the display
  933.     move.w    d0,gdp_Width(a5)
  934.  
  935. .ll3    tst.w    gdp_Height(a5)
  936.     bpl.s    .ll4
  937.     move.w    bm_Rows(a0),gdp_Height(a5)
  938.  
  939. .ll4    move.l    gdp_dsp(a5),a2
  940.     move.l    dsp_ViewPort(a2),a0
  941.     CALLGFX InitVPort
  942.     move.l    dsp_ViewPort(a2),a1
  943.     move.l    dsp_RasInfo(a2),vp_RasInfo(a1)        ; Link RI - VP
  944.     move.l    gdp_ColorMap(a5),vp_ColorMap(a1)    ; Link CM - VP
  945.     move.w    gdp_Width(a5),vp_DWidth(a1)        ; Set Width
  946.     move.w    gdp_Height(a5),vp_DHeight(a1)        ; and height VP
  947.     move.w    gdp_Modes(a5),vp_Modes(a1)        ; Set DispMode
  948.  
  949.     move.l    dsp_View(a2),a1
  950.     CALLGFX    InitView
  951.     move.l    dsp_View(a2),a1
  952.     move.l    dsp_ViewPort(a2),v_ViewPort(a1)        ; LINK VP - V
  953.     move.w    gdp_Modes(a5),v_Modes(a1)
  954.  
  955.     move.l    dsp_RasInfo(a2),a1            ; LINK BM - RI
  956.     move.l    gdp_BM1(a5),ri_BitMap(a1)
  957.  
  958.     andi.w    #V_DUALPF,gdp_Modes(a5)
  959.     beq    .ll5
  960. ** Dualplay field , we need an extra Bitmap and RasInfo.
  961.     move.l    #ri_SIZEOF,d0
  962.     move.l    #MEMF_CLEAR!MEMF_PUBLIC,d1
  963.     CALLEX    AllocMem
  964.     move.l    gdp_dsp(a5),a1
  965.     move.l    dsp_RasInfo(a1),a1
  966.     move.l    d0,ri_Next(a1)        ; Link RasInfo1 with RasInfo2 
  967.     bne    .ll6
  968.     moveq.l    #3,d7
  969.     bra    gdp_error
  970. .ll6    move.l    d0,a0
  971.     move.l    gdp_BM2(a5),ri_BitMap(a0)    ; Link Bitmap2 with RasInfo2
  972.  
  973. .ll5    move.l    gdp_dsp(a5),d0    ; Return a pointer to the display struct. 
  974.     unlk    a5
  975.     movem.l    (sp)+,GDP_regs
  976.     rts
  977.  
  978. gdp_error            ; Deallocate the allocated.
  979.     move.l    gdp_ColorMap(a5),d0
  980.     beq    .ll1
  981.     move.l    d0,a0
  982.     CALLGFX    FreeColorMap
  983. .ll1    move.l    gdp_dsp(a5),d0
  984.     beq    .ll2
  985.     move.l    d0,a0
  986.     move.l    a0,-(sp)
  987.     move.l    dsp_RasInfo(a0),a0    ; Do we have an extra RasInfo?
  988.     move.l    ri_Next(a0),d0
  989.     beq    .ll1_1
  990.     move.l    d0,a1
  991.     move.l    #ri_SIZEOF,d0
  992.     CALLEX    FreeMem
  993. .ll1_1    move.l    (sp)+,a0
  994.     CALLEX    FreeEntry
  995. .ll2    clr.l    d0        ; There was an error.
  996.     move.l    d7,d1        ; Error code.
  997.     unlk    a5
  998.     movem.l    (sp)+,GDP_regs
  999.     rts
  1000.  
  1001. ******* ExtGfx.s/FreeDisplay ******************************************
  1002. *
  1003. *   NAME    
  1004. *    FreeDisplay -- Dealocate the memory allocated by GetDisplay.
  1005. *   SYNOPSIS
  1006. *    FreeDisplay(Display)
  1007. *            A0
  1008. *    void FreeDisplay(struct Display *)
  1009. *   FUNCTION
  1010. *    Deallocate the colormap.
  1011. *    Deallocate the memory for the display structure.
  1012. *    If there is an extra RasInfo then deallocate it.
  1013. *   INPUTS
  1014. *    Display - A pointer to a Display structure.
  1015. *   RESULT
  1016. *
  1017. *   EXAMPLE
  1018. *
  1019. *   NOTES
  1020. *    You can FreeDisplay(NULL) !
  1021. *   BUGS
  1022. *
  1023. *   SEE ALSO
  1024. *    GetDisplay()
  1025. ******************************************************************************
  1026. *
  1027. *
  1028.  
  1029. FreeDisplay
  1030.     move.l    a0,d0
  1031.     beq.s    .exit
  1032.     move.l    a0,-(sp)
  1033.     move.l    dsp_RasInfo(a0),a0    ; Do we have an extra RasInfo?
  1034.     move.l    ri_Next(a0),d0
  1035.     beq    .ll1
  1036.     move.l    d0,a1
  1037.     move.l    #ri_SIZEOF,d0
  1038.     CALLEX    FreeMem
  1039. .ll1    move.l    (sp),a0
  1040.     move.l    dsp_ViewPort(a0),a0
  1041.     move.l    vp_ColorMap(a0),a0
  1042.     CALLGFX    FreeColorMap
  1043.     move.l    (sp)+,a0
  1044.     CALLEX    FreeEntry
  1045. .exit    rts
  1046.  
  1047.  
  1048. ******* ExtGfx.s/CreatePort ******************************************
  1049. *
  1050. *   NAME    
  1051. *    CreatePort -- Create a MessagePort.
  1052. *   SYNOPSIS
  1053. *    MsgPort=CreatePort(Name,Priority)
  1054. *    D0                 A0   D0
  1055. *    struct MsgPort *CreatePort(STRPTR *,INT)
  1056. *   FUNCTION
  1057. *    Allocates a SignalBit and memory for a MsgPort structure
  1058. *    and initializes the structure.
  1059. *   INPUTS
  1060. *    Name -  A null terminated string.
  1061. *    Priority - The priority for the port to be created.
  1062. *   RESULTS
  1063. *    A pointer to a to the Message Port.
  1064. *    A NULL pointer in case of an error.
  1065. *    If you supplied a name the port will be made public using the
  1066. *    funtion AddPort.
  1067. *   BUGS
  1068. *    ?
  1069. *   SEE ALSO
  1070. *    DeletePort
  1071. ******************************************************************************
  1072. *
  1073. *
  1074.  
  1075. CreatePort    ; (Name,Priority),A0,D0 -> (MsgPort),D0
  1076.  
  1077.     move.l    a2,-(sp)
  1078.  
  1079.     movem.l    a0/d0,-(sp)        ; Save name & pri
  1080.  
  1081.     move.l    #MP_SIZE,d0        ; Alloc mem for msg-port.
  1082.     move.l    #MEMF_CLEAR!MEMF_PUBLIC,d1
  1083.     CALLEX    AllocMem
  1084.     move.l    d0,a2
  1085.     tst.l    d0
  1086.     beq    .err1            ; Alloc mem failed
  1087.  
  1088.     moveq.l    #-1,d0            ; Alloc signal for msg-port.
  1089.     CALLEX    AllocSignal
  1090.     move.b    d0,MP_SIGBIT(a2)    
  1091.     beq    .err2            ; All signals in use.
  1092.  
  1093.     movem.l    (sp)+,a0/d0        ; restore name & pri
  1094.     move.l    a0,LN_NAME(a2)        ; link name to msgport
  1095.     move.b    d0,LN_PRI(a2)        ; set pri for msgport
  1096.     move.b    #PA_SIGNAL,MP_FLAGS(a2)
  1097.  
  1098.     suba.l    a1,a1            ; Find the Task that called
  1099.     CALLEX    FindTask        ; this function.
  1100.     move.l    d0,MP_SIGTASK(a2)
  1101.  
  1102.     move.b    #NT_MSGPORT,LN_TYPE(a2)
  1103.  
  1104.     tst.l    LN_NAME(a2)        ; test if the port has a name
  1105.     beq.s    .ll1    
  1106.     move.l    a2,a1
  1107.     CALLEX    AddPort            ; if so make the port public
  1108.     move.l    a2,d0            ; Point to the port in D0 (result)
  1109.     bra.s    .ll2
  1110.     
  1111. .ll1    move.l    a2,d0
  1112.     adda.l    #MP_MSGLIST,a2
  1113.     NEWLIST    a2
  1114.  
  1115. .ll2    move.l    (sp)+,a2
  1116.     rts
  1117. .err2
  1118.     move.l    a2,a1
  1119.     move.l    #MP_SIZE,d0
  1120.     CALLEX    FreeMem
  1121. .err1
  1122.     CLEAR    d0
  1123.     movem.l    (sp)+,a0/d0        remove name & pri from stack
  1124.     move.l    (sp)+,a2
  1125.     rts
  1126.  
  1127. ******* ExtGfx.s/DeletePort ******************************************
  1128. *
  1129. *   NAME    
  1130. *    DeletePort -- Free the memory and signal allocted
  1131. *              for a MessagePort.
  1132. *   SYNOPSIS
  1133. *    DeletePort(MsgPort)
  1134. *                 A0   
  1135. *    void DeletePort(struct MsgPort *)
  1136. *   FUNCTION
  1137. *    Free the memory allocated for the MsgPort Structure, and
  1138. *    free the SignalBit used by the message port. If the port has a 
  1139. *    name and therefore is public it will be removed using RemPort.
  1140. *   INPUTS
  1141. *    A pointer to a message port.
  1142. *   RESULTS
  1143. *    None.
  1144. *   BUGS
  1145. *    ?
  1146. *   SEE ALSO
  1147. *    CreatePort
  1148. *
  1149. ******************************************************************************
  1150. *
  1151. *
  1152.  
  1153. DeletePort    ; (MSGPort),a0
  1154.  
  1155.     tst.l    LN_NAME(a0)        test if the port has a name
  1156.     beq.s    .ll1            and therefore is public 
  1157.     move.l    a0,-(sp)
  1158.     move.l    a0,a1
  1159.     CALLEX    RemPort            remove the port from public use
  1160.     move.l    (sp)+,a0
  1161.     
  1162. .ll1    CLEAR    d0
  1163.     move.b    MP_SIGBIT(a0),d0
  1164.     CALLEX    FreeSignal        free signal bit
  1165.     move.l    a0,a1
  1166.     move.l    #MP_SIZE,d0        free memory allocted for port
  1167.     CALLEX    FreeMem
  1168.  
  1169.     rts
  1170.  
  1171. ******* ExtGfx.s/CreateStdIO ******************************************
  1172. *
  1173. *   NAME    
  1174. *    CreatePort -- Create a MessagePort.
  1175. *   SYNOPSIS
  1176. *    StdIO=CreateStdIO(MsgPort)
  1177. *    d0            a0
  1178. *    struct IORequest *CreateStdIO(MsgPort *)
  1179. *   FUNCTION
  1180. *    Allocates memory for a IORequest structure and initializes the
  1181. *    structure.
  1182. *   INPUTS
  1183. *    MsgPort - A pointer to an already initialized message port to
  1184. *          be used for this I/O request's reply port.
  1185. *   RESULTS
  1186. *    Returns a pointer to the new I/O Request block, or NULL if.
  1187. *    the request failed.
  1188. *   BUGS
  1189. *    ?
  1190. *   SEE ALSO
  1191. *    CreateExtIO, DeleteStdIO
  1192. ******************************************************************************
  1193. *
  1194. *
  1195.  
  1196. CreateStdIO    ; (MsgPort),a0
  1197.  
  1198.     move.l    #IOSTD_SIZE,d0
  1199.     jsr    CreateExtIO
  1200.     rts
  1201.  
  1202.  
  1203. ******* ExtGfx.s/CreateExtIO ******************************************
  1204. *
  1205. *   NAME
  1206. *    CreateExtIO -- Create an I/O request.
  1207. *   SYNOPSIS
  1208. *    ExtIO=CreateExtIO(MsgPort,Size)
  1209. *    d0          a0      d0
  1210. *    struct IORequest *CreateExtIO(struct MsgPort *,INT)
  1211. *   FUNCTION
  1212. *    Allocates memory for and initializes a new I/O request block
  1213. *    of a user-specified number of bytes. The number of bytes MUST
  1214. *    be greater than the length of a Exec message, or some very nasty
  1215. *    things will happen.
  1216. *    structure.
  1217. *   INPUTS
  1218. *    MsgPort - A pointer to an already initialized message port to
  1219. *          be used for this I/O request's reply port.
  1220. *    size    - the size of the I/O request to be created.
  1221. *   RESULTS
  1222. *    Returns a pointer to the new I/O Request block, or NULL if.
  1223. *    the request failed.
  1224. *   BUGS
  1225. *    ?
  1226. *   SEE ALSO
  1227. *    DeleteExtIO
  1228. ******************************************************************************
  1229. *
  1230. *
  1231.  
  1232. CreateExtIO    ; (Size,MsgPort),d0,a0 -> (IOReq),d0
  1233.  
  1234.     move.w    d0,-(sp)
  1235.     move.l    a0,-(sp)
  1236.  
  1237.     move.l    #MEMF_CLEAR!MEMF_PUBLIC,d1
  1238.     CALLEX    AllocMem
  1239.     tst.l    d0
  1240.     beq    .err
  1241.     move.l    d0,a1
  1242.  
  1243.     move.b    #NT_MESSAGE,LN_TYPE(a1)
  1244.     move.l    (sp)+,MN_REPLYPORT(a1)
  1245.     move.w    (sp)+,MN_LENGTH(a1)
  1246.  
  1247.     rts
  1248. .err
  1249.     move.l    (sp)+,a0
  1250.     move.w    (sp)+,d1
  1251.  
  1252.     rts
  1253.  
  1254.  
  1255. ******* ExtGfx.s/DeleteStdIO ******************************************
  1256. *
  1257. *   NAME
  1258. *    DeleteStdIO -- 
  1259. *                   return memory allocated for Standard IO Structure.
  1260. *   SYNOPSIS
  1261. *    DeleteStdIO(StdIO)
  1262. *               a0
  1263. *    void DeleteStdIO(struct IORequest *)
  1264. *   FUNCTION
  1265. *    Free the memory allocted for IO request.
  1266. *   INPUTS
  1267. *    A pointer to a standard IO structure.
  1268. *   RESULTS
  1269. *    None.
  1270. *   BUGS
  1271. *    ?
  1272. ******************************************************************************
  1273. *
  1274. *
  1275.  
  1276. ******* ExtGfx.s/DeleteExtIO ******************************************
  1277. *
  1278. *   NAME
  1279. *    DeleteExtIO --
  1280. *                   return memory allocated for extended IO Structure.
  1281. *   SYNOPSIS
  1282. *    DeleteExtIO(ExtIO)
  1283. *             a0
  1284. *    void DeleteExtIO(struct IORequest *)
  1285. *   FUNCTION
  1286. *    Free the memory allocted for IO request.
  1287. *   INPUTS
  1288. *    A pointer to a extended IO structure.
  1289. *   RESULTS
  1290. *    None.
  1291. *   BUGS
  1292. *    ?
  1293. ******************************************************************************
  1294. *
  1295. *
  1296.  
  1297. DeleteStdIO
  1298.  
  1299. DeleteExtIO    ; (IOReq),a0
  1300.  
  1301.     move.b    #-1,LN_TYPE(a0)
  1302.     move.l    #-1,IO_DEVICE(a0)
  1303.     move.l    #-1,IO_UNIT(a0)
  1304.     clr.l    d0
  1305.     move.w    MN_LENGTH(a0),d0
  1306.     move.l    a0,a1
  1307.     CALLEX    FreeMem
  1308.  
  1309.     rts
  1310.  
  1311.  
  1312. ******** DATA STRUCTURES ***********
  1313.  
  1314. dsp_Template
  1315.     dcb.b    LN_SIZE
  1316.     dc.w    3
  1317.     dc.l    MEMF_PUBLIC!MEMF_CLEAR
  1318.     dc.l    v_SIZEOF
  1319.     dc.l    MEMF_PUBLIC!MEMF_CLEAR
  1320.     dc.l    vp_SIZEOF
  1321.     dc.l    MEMF_PUBLIC!MEMF_CLEAR
  1322.     dc.l    ri_SIZEOF
  1323.  
  1324.     end
  1325.